cargo-tauri.hook

Tauri چارچوبی برای ساخت برنامه‌های دسکتاپ کوچک‌تر، سریع‌تر و امن‌تر با فرانت‌اند وب است.

در Nixpkgs، cargo-tauri.hook فازهای پیش‌فرض ساخت و نصب را بازنشانی می‌کند.

قطعه‌کد نمونه

{
  lib,
  stdenv,
  rustPlatform,
  fetchNpmDeps,
  cargo-tauri,
  glib-networking,
  nodejs,
  npmHooks,
  openssl,
  pkg-config,
  webkitgtk_4_1,
  wrapGAppsHook4,
}:

rustPlatform.buildRustPackage (finalAttrs: {
  # ...

  cargoHash = "...";

  # Assuming our app's frontend uses `npm` as a package manager
  npmDeps = fetchNpmDeps {
    name = "${finalAttrs.pname}-${finalAttrs.version}-npm-deps";
    inherit (finalAttrs) src;
    hash = "...";
  };

  nativeBuildInputs = [
    # Pull in our main hook
    cargo-tauri.hook

    # Setup npm
    nodejs
    npmHooks.npmConfigHook

    # Make sure we can find our libraries
    pkg-config
  ]
  ++ lib.optionals stdenv.hostPlatform.isLinux [ wrapGAppsHook4 ];

  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
    glib-networking # Most Tauri apps need networking
    openssl
    webkitgtk_4_1
  ];

  # Set our Tauri source directory
  cargoRoot = "src-tauri";
  # And make sure we build there too
  buildAndTestSubdir = finalAttrs.cargoRoot;

  # ...
})

متغیرهای کنترل‌کننده cargo-tauri

متغیرهای اختصاصی Tauri

tauriBuildFlags

پرچم‌های ارسال‌شده به cargo tauri build را کنترل می‌کند.

tauriBundleType

نوع باندل برای ساخت.

dontTauriBuild

استفاده از tauriBuildHook را غیرفعال می‌کند.

dontTauriFixup

فاز پیش از اصلاح (pre fixup) مربوط به tauriFixupHook را غیرفعال می‌کند.

dontTauriInstall

استفاده از tauriInstallPostBuildHook و tauriInstallHook را غیرفعال می‌کند.

متغیرهای پشتیبانی‌شده

همراه با موارد موجود در ، متغیرهای زیر که توسط cargoBuildHook و cargoInstallHook استفاده می‌شوند، توسط قلاب راه‌اندازی cargo-tauri نیز پشتیبانی می‌شوند.

• buildAndTestSubdir
• cargoBuildType
• cargoBuildNoDefaultFeatures
• cargoBuildFeatures